NAME
     SelectSpec - select spectra
     SelectPeak - select peaks
     SelectPrim - select primitives

SYNOPSIS
     SelectSpec expr
     SelectPeak expr
     SelectPrim expr

DESCRIPTION
     Select spectra, peaks or primitives that satisfy a
     conditions specified by an expression. The expression
     must give a result of type boolean (truth value).

     There are two special values not covered by the
     expression syntax below. If an empty string is given
     as expression, everything is selected. If the value
     "0" is given, nothing is selected (i. e. everything
     deselected).

     The following is a formal sytax description of
     expressions in EBNF notation. Typical examples are
     shown in the next section.

       expr       = andExpr { "|" andExpr } .
       andExpr    = relExpr { "&" relExpr } .
       relExpr    = simpleExpr [ relOp setExpr ] .
       relOp      = "=" | "!=" | "<=" |
                    "<" | ">=" | ">" .
       setExpr    = rangeExpr { "," rangeExpr } .
       rangeExpr  = simpeExpr [ ".." simpleExpr ] .
       simpleExpr = term { addOp term } .
       addOp      = "+" | "-" .
       term       = factor { mulOp factor } .
       mulOp      = "*" | "/" | "%" .
       factor     = [ "-" | "sqrt" | "log" | "!" ] primary .
       primary    = constant | designator | "(" expr ")" .
       constant   = string | int | float .
       designator = [ qual "." ] field [ "[" int "]" ] .
       qual       = "spec" | "peak" | "prim"
       field      = "num" | "number" | "name" | "attr" |
                    "amp" | "symm" | "unif" | "qual" |
                    "shift0" | "shift1" |
		    "shift2" | "shift3" |
                    "width0" | "width1" |
		    "width2" | "width3" |
                    propertyName .

     For selecting items by their number or name,
     there is a shorter notation of the form:

       expr     = exprPart { exprPart } .
       exprPart = [ "#" set ] .
       set      = sel { "," sel } .
       sel      = string | range .
       range    = int ".." int | int "-" int .

     Strings are not quoted in this notation.

     The full and the short notation can be mixed, in
     this case a part written in the short notation
     behaves like a primary with a boolean value.

EXAMPLES
     SelectSpec 'num > 2'
         # all spectra but the first two
     SelectPeak 'qual > 0.3 & width0 > 4.0 & width1 > 1.0'
         # all peaks with minimal quality of 0.3 and
	 # minimal line widths 4.0 and 1.0

SEE ALSO
     DialSelect, DefPropMol,... , DialMol

DATE
     960913
